mIRC32 - Ejemplos ya programados: Terminal para conexiones TCP. Fecha creación: 16/12/99 - Última revisión: 16/12/99
 
; ###########################
; 
;     Terminal Sock v1.0
;      By [SaRRiO] 1999
;     sarrio@univers.org
;  http://sarrio.univers.org
;
; ###########################


; para empezar a usar la terminal usa: /termwindow y mira en el menu de la ventana que se abrira...
; abre la ventana de la terminal

alias termwindow {
  window -ake @Terminal 200 100 500 300
  titlebar @Terminal Sock
}

; el menu de la ventana @Terminal

menu @Terminal {
  sclick { }
  %terminal.iphost ( %terminal.puerto ):termopen %terminal.iphost %terminal.puerto
  -
  nueva conexion:termopen $$?="IP o HOST?" $$?="Puerto?"
  -
  cerrar conexion:{
    sockclose TERMINAL*
    echo @Terminal 10-----------------------------------------------------
    echo @Terminal 2CONEXION CERRADA POR EL USUARIO LOCAL:12 $me
    echo @Terminal 10-----------------------------------------------------
  }
}

; abre una conexion TCP con la IP indicada

alias termopen {
  set %terminal.iphost $1 
  set %terminal.puerto $2
  sockopen TERMINAL $1 $2 
}

; comprueba si conecta o no con la IP/HOST indicada/o

on 1:SOCKOPEN:TERMINAL*:{

  if ($sockerr > 0) {  
    echo @Terminal 12ERROR!2 No se puede conectar con esa IP -10 $sock($sockname,1).ip 2- 
    sockclose $sockname
    return
  }
  else {
    echo @Terminal 3AHORA ESTAS CONECTADO A4 $sock($sockname,1).ip 3POR EL PUERTO4 $sock($sockname,1).port
    echo @Terminal 6-------------------------------------------------------------------------- 
    echo @Terminal 0.
  }

}

; comprueba si hay texto en el buffer y si lo hay lo muestra en @Terminal

on 1:SOCKREAD:TERMINAL*:{
  sockread %terminal.read
  echo @Terminal %terminal.read
  unset %terminal.read
}

; si escribes algo en el editbox de @Terminal y no es un comando de mIRC, manda el texto
; a la IP indicada por el puerto que estas conectado con la terminal

on 1:INPUT:@Terminal:{
  if ($left($1,1) != /) { 
    sockwrite -tn TERMINAL $parms
    echo @Terminal 7>6 $parms
    halt
  }
}

; si la conexion se cierra por culpa del servidor/ip/host te lo dice...

on 1:SOCKCLOSE:TERMINAL:{
  echo @Terminal 10-----------------------------------------------------
  echo @Terminal 2CONEXION CERRADA POR LA IP:12 $sock($sockname,1).ip
  echo @Terminal 10-----------------------------------------------------
}

; NOTAS: esta terminal si que es sencilla... pero es lo más básico, osea recibir y mandar texto por sockets...
; si quereis copiar este script, por favor mandame un mail comunicandomelo,
; no pondre ninguna pega si me mencionas en los créditos y me avisas.
 Volver a la página principal